找到四个 10 的所有表达式

我有一个部分解决方案，我将在这里概述，希望它能让你动起来，你可以找到完整的解决方案。

您需要的第一个工具是能够进行一些表达式：

build_expr(X, Y, X+Y).
build_expr(X, Y, X*Y).
build_expr(X, Y, X-Y).
build_expr(X, Y, X/Y).

这定义了build_expr/3，它接受两个变量或表达式并产生一个新的表达式。这就是我们将如何排列运算符。现在我们需要一种方法来处理列表，所以让我们定义一次对列表进行操作build_expr/2：

% base case: we are down to two variables and call build_expr/3
build_expr([X,Y], Expr) :- build_expr(X, Y, Expr).
% inductive case: make the expression on the rest of the list and combine
% with the leading variable here
build_expr([X|Rest], Expr) :-
build_expr(Rest, Expr0),
build_expr(X, Expr0, Expr).

让我们得到一些解决方案，以便我们了解它正在做的事情：

3 ?- build_expr([10,10,10,10],X).
X = 10+(10+(10+10)) ;
X = 10*(10+(10+10)) ;
X = 10-(10+(10+10)) ;
X = 10/(10+(10+10)) ;
X = 10+10*(10+10) ;
X = 10*(10*(10+10)) ;
X = 10-10*(10+10) ;
X = 10/(10*(10+10)) ;
X = 10+(10-(10+10)) ;
X = 10*(10-(10+10)) ;
X = 10-(10-(10+10)) ;
X = 10/(10-(10+10)) ;

这对我来说看起来还不错。但就像我说的，我只是在生成右倾的树。你将不得不修改或替换build_expr/2以产生其他形状，如果它们真的重要(我不相信它们很重要(。

现在，让我们通过捆绑评估来简化下一步：

build_eval(L, Value) :- build_expr(L, Expr), Value is Expr.

现在我们应该能够使用setof/3找到所有独特的解决方案：

6 ?- setof(X, build_eval([10,10,10,10],X), Results).
ERROR: Arithmetic: evaluation error: `zero_divisor'
ERROR: In:
ERROR:   [15] _582 is 10/(10* ...)
ERROR:   [14] build_eval([10,10|...],_622) at /Users/dlyons/fourtens.pl:11
ERROR:   [13] '$bags':findall_loop(_664,user:build_eval(...,_682),_668,[]) at /usr/local/Cellar/swi-prolog/7.6.4/libexec/lib/swipl-7.6.4/boot/bags.pl:97
ERROR:   [12] setup_call_catcher_cleanup('$bags':'$new_findall_bag','$bags':findall_loop(_728,...,_732,[]),_710,'$bags':'$destroy_findall_bag') at /usr/local/Cellar/swi-prolog/7.6.4/libexec/lib/swipl-7.6.4/boot/init.pl:443
ERROR:    [8] '$bags':setof(_770,user:build_eval(...,_786),_774) at /usr/local/Cellar/swi-prolog/7.6.4/libexec/lib/swipl-7.6.4/boot/bags.pl:240
ERROR:    [7] <user>
ERROR:
ERROR: Note: some frames are missing due to last-call optimization.
ERROR: Re-run your program in debug mode (:- debug.) to get more detail.
ERROR:   [13] '$bags':findall_loop(_664,user:build_eval(...,_682),_668,[]) aabort
% Execution Aborted

哎呀。除以零误差。没问题，让我们抓住它并在这些情况下失败：

9 ?- setof(X, catch(build_eval([10,10,10,10],X), E, fail), Results), writeln(Results).
[-990,-900,-190,-100,-80,-20,-1,-0.1111111111111111,
0,0.01,0.05,0.09090909090909091,0.3333333333333333,1.0,1,
5.0,9.5,9.9,10,10.1,10.5,20.0,20,40,100.0,100,
120,210,300,1010,1100,2000,10000]

我在那里稍微摆弄了一下格式，但我认为这是一个很好的解决方案，但我已经可以看到一个缺少的解决方案：(10+10(*(10+10(=400。因此，您必须在build_expr/2上更具创造力，以使其产生其他形状的树。

编辑：添加其余解决方案

我通过@gusbro找到了一个答案，它提供了一种枚举树的方法。我无法让它与我在那里做的递归技巧一起工作(也许其他人会向我展示一个非常简单的技巧(，但我能够使他的答案适应你的问题，即：

build_tree([I1,I2|Items], Expr) :-
append([L0|LR], [R0|RR], [I1,I2|Items]),
build_tree([L0|LR], Left),
build_tree([R0|RR], Right),
build_expr(Left, Right, Expr).
build_tree([E], E).

为什么我使用[L0|LR]和[R0|RR]而不是LeftList和RightList之类的？这就是我将@gusbro的数值约束转换为列表长度约束并确保我在左侧和右侧列表中始终至少有一个元素的方式，因此我对build_tree/2的递归调用将成功。

将build_expr/3从上面简化为单个运算符，您可以看到这会产生您期望的所有各种风格：

?- build_tree([10,10,10,10],X).
X = 10+(10+(10+10)) ;
X = 10+(10+10+10) ;
X = 10+10+(10+10) ;
X = 10+(10+10)+10 ;
X = 10+10+10+10 ;
false.

将其切换回来，因为我们仍在使用前面示例中的build_expr/3函数。我使用这个build_eval/2谓词简化了评估：

build_eval(L, Value) :- 
build_tree(L, Expr), catch(Value is Expr, _, fail).

最终解决方案如下所示：

?- setof(X, build_eval([10,10,10,10], X), Res), writeln(Res).
[-990,-900,-190,-100,-99,-90,-80,-20,-19,-10,-9.9,-9.5,-9,
-8,-1.1111111111111112,-1,-0.9,-0.1111111111111111,
0,0.01,0.05,0.09090909090909091,0.1111111111111111,
0.2,0.3333333333333333,0.9,0.9090909090909091,1.0,1,
1.1,1.1111111111111112,2,3,5.0,5,8,9,9.5,9.9,10,10.1,10.5,11,
12,19,20.0,20,21,40,80,90,99,100.0,100,101,110,120,190,
200,210,300,400,900,990,1010,1100,2000,10000]

哇，很多选择，确切地说是 68 个！