链接到通过调用ExternalProject_Add生成的动态库

CMake link to dynamic library generated by call to ExternalProject_Add

本文关键字：动态 Add 调用 ExternalProject 链接      更新时间：2023-10-16

我有一个小的测试程序，我想链接到GLFW。我目前能够使用ExternalProject_Add命令下载、配置和构建.dll。当我构建我的测试程序时，我得到一个无法运行的可执行文件，因为它找不到.dll。如果我手动复制.dll到可执行文件所在的目录，它就能正常运行。

如何让我的可执行文件正确链接到库?

是否有一种方法可以自动复制.dll到需要的地方?

在打包程序时，确保库可用且易于访问的最佳方法是什么?

CMakeLists.txt: 

cmake_minimum_required (VERSION 2.8)
project (GLFW-test)
set( CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/app )
set( CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib )
# Include OpenGL
find_package(OpenGL REQUIRED)
if (OPENGL_FOUND)
    include_directories(${OPENGL_INCLUDE_DIR})
    link_libraries(${OPENGL_LIBRARIES})
endif()
# Add directories for library linkage
set(GLFW_LIB_DIR ${CMAKE_BINARY_DIR}/downloads/deps/Build/GLFW_EX/src)
link_directories(${GLFW_LIB_DIR})
# Download and unpack dependencies at configure time
configure_file(deps-CMakeLists.txt downloads/CMakeLists.txt)
execute_process(COMMAND ${CMAKE_COMMAND} -G "${CMAKE_GENERATOR}" .
  WORKING_DIRECTORY ${CMAKE_BINARY_DIR}/downloads)
execute_process(COMMAND ${CMAKE_COMMAND} --build .
  WORKING_DIRECTORY ${CMAKE_BINARY_DIR}/downloads)
add_subdirectory(${CMAKE_BINARY_DIR}/downloads/deps/Source/GLFW_EX
                 ${CMAKE_BINARY_DIR}/downloads/deps/Build/GLFW_EX
                 EXCLUDE_FROM_ALL )
include_directories(${CMAKE_BINARY_DIR}/downloads/deps/Source/GLFW_EX/include)
add_executable(GLFW-test src/GLFW-test.cpp)
target_link_libraries (GLFW-test glfw3 ${OPENGL_LIBRARIES})
add_custom_command(TARGET GLFW-test POST_BUILD        # Adds a post-build event to MyTest
    COMMAND ${CMAKE_COMMAND} -E copy_if_different     # which executes "cmake - E copy_if_different..."
        "${GLFW_LIB_DIR}/glfw3.dll"                   # <--this is in-file
        $<TARGET_FILE_DIR:GLFW-test>)                 # <--this is out-file path

dep-CMakeLists.txt: 

cmake_minimum_required (VERSION 2.8)
project (GLFW-dl)
include(ExternalProject)
set_directory_properties(PROPERTIES EP_BASE "./deps/")
# Include GLFW
ExternalProject_Add (
       GLFW_EX
       GIT_REPOSITORY "https://github.com/glfw/glfw.git"
       GIT_TAG "master"
       CMAKE_ARGS -DGLFW_BUILD_EXAMPLES=OFF
                  -DGLFW_BUILD_TESTS=OFF
                  -DGLFW_BUILD_DOCS=OFF
                  -DGLFW_INSTALL=OFF
                  -DBUILD_SHARED_LIBS=ON
       UPDATE_COMMAND ""
       TEST_COMMAND      "" )

更新:我使用ExternalProject_Add的方式在这个网站上有描述:https://crascit.com/2015/07/25/cmake-gtest/它允许在我的项目的配置阶段只配置和构建一次外部项目。我对他们的测试程序的目录做了一些修改，这样当我最终添加更多的外部项目时，事情会变得简单一些。网站上的测试项目似乎没有考虑动态库，这正是我想做的。

更新2:

我添加了2个set命令来帮助清理构建目录对CMakeLists文件的顶部。我还在底部添加了一个命令，该命令将从ExternalProject_Add命令构建的.dll复制到我需要它的地方(靠近最终可执行文件)。这似乎适用于Windows，但它似乎有点粗糙，并不能解决我的IDE(目前是Eclipse)中的错误。还有更好的方法吗?

有用相关主题:

  • 设置外部项目的RPATH ?
  • Cmake在Windows上没有't添加共享库路径(适用于linux)
  • 如何将DLL文件复制到使用CMake的可执行文件的同一文件夹中?

如何让我的可执行文件正确链接到库?

正如你的第二个链接所述，除了将.dll与可执行文件放在同一个目录下，没有其他方法。

是否有一种方法可以自动复制.dll到需要的地方?

在你的主项目中，你已经使用变量CMAKE_RUNTIME_OUTPUT_DIRECTORY作为安装目录，可执行文件和.dll应该在构建后放置。您可以将此变量传递给ExternalProject_add，以强制它使用相同的约定:

ExternalProject_Add (...
    CMAKE_ARGS -DCMAKE_RUNTIME_OUTPUT_DIRECTORY=${CMAKE_RUNTIME_OUTPUT_DIRECTORY}
    ...
)

在打包程序时，确保库可用且易于访问的最佳方法是什么?

package只使用项目的install-tree。因此，将可执行文件和库安装到同一位置就足够了:

set(INSTALL_RUNTIME_DIR bin)
install(TARGETS GLFW-test
    RUNTIME DESTINATION ${INSTALL_RUNTIME_DIR}
)
install(FILES ${CMAKE_RUNTIME_OUTPUT_DIRECTORY}/glfw3.dll
    DESTINATION ${INSTALL_RUNTIME_DIR}
)

注意，从外部项目获得的目标GLFW_EX没有特殊类型(如可执行文件或库)，因此您需要使用普通文件名安装其可交付成果。

相关文章：