CMake 选项，用于禁用对特定平台的特定文件的编译

CMake Option to Disable Compilation on Specific Files for Specific Platforms

本文关键字：平台 文件 编译 选项 用于 CMake      更新时间：2023-10-16

我正在使用CMake来定义我的项目。 我的目标是让特定于平台的文件易于访问，以便在所有平台上进行编辑、搜索、浏览和源代码控制。

我目前在 cmake 描述中分隔了特定于平台的文件。 我的 CMakeLists.txt 文件如下所示：

 Foo.hpp
 ${platform_directory}/Foo.cpp

然后在磁盘上我有这样的东西：

 Foo.hpp
 win
  `- Foo.cpp 
 osx
  `- Foo.cpp

在生成的项目文件中，它看起来像：

 Foo.hpp
 Foo.cpp (platform-specific version)

这对于编译器来说是完美的，但这意味着开发人员缺乏用于非本机平台特定文件的 IDE 工具。

我正在寻找的是这样的东西（在Xcode中）：

 Foo.hpp
 Foo.cpp (OS X version)
 win
  `- Foo.cpp (file type set to plain text)

或者在Visual Studio中：

 Foo.hpp
 Foo.cpp (Windows version)
 osx
  `- Foo.cpp (build action set to none)

关于如何设置 CMake 这样的东西的任何想法？

一种方法是添加一个没有构建规则的自定义目标，特别是保存不属于给定平台构建的文件; 例如

if(WIN32)
  add_library(Foo Foo.hpp win/Foo.cpp)
  add_custom_target(NonWindows SOURCES osx/Foo.cpp)
  source_group("osx" osx/Foo.cpp)
else(APPLE)
  add_library(Foo Foo.hpp osx/Foo.cpp)
  add_custom_target(NonApple SOURCES win/Foo.cpp)
  source_group("win" win/Foo.cpp)
endif()

另一种选择（可能更接近您想要的，但更"hacky"）是将所有文件添加到目标，但将构建不需要的文件标记为HEADER_FILE_ONLY：

add_library(Foo Foo.hpp win/Foo.cpp osx/Foo.cpp)
if(WIN32)
  set_source_files_properties(osx/Foo.cpp PROPERTIES HEADER_FILE_ONLY TRUE)
  source_group("osx" osx/Foo.cpp)
else(APPLE)
  set_source_files_properties(win/Foo.cpp PROPERTIES HEADER_FILE_ONLY TRUE)
  source_group("win" win/Foo.cpp)
endif()

Fraser 建议的HEADER_FILE_ONLY技术效果很好，但明确配置哪些文件应该在哪个平台上遵守会变得乏味。

给定一个 CMake 函数，如下所示：

function (DisableCompilingPlatformSpecificSources file_list)
   foreach(file ${file_list})
      if (
         ((${file} MATCHES "^(.*)Win32\.cpp") AND NOT WIN32) OR
         ((${file} MATCHES "^(.*)Unix\.cpp")  AND NOT UNIX)  OR
         ((${file} MATCHES "^(.*)Apple\.cpp") AND NOT APPLE)
      )
         set_source_files_properties(
            ${file}
            PROPERTIES HEADER_FILE_ONLY TRUE
         )
      endif()
   endforeach()
endfunction()

我们可以通过后缀来控制特定于平台的源。 例如：

set(all_sources
   Foo.hpp
   FooWin32.cpp # windows-specific
   FooApple.cpp # apple-specific
)
DisableCompilingPlatformSpecificSources("${all_sources}")
add_executable(foo ${all_sources})

这与 gyp 处理特定于平台的文件的方式非常相似，并且可以轻松扩展以支持所需的其他后缀。

相关文章：